TreeMig.f90

Go to the documentation of this file.

!==============================================================================
 
!==============================================================================
 
SUBROUTINE treemig(doParallel)  
    use filelistmodule, only: bioclimate_file, closefile, readcontrolparsandinitfiles
    use netcdftmmodule, only: preparenetcdfoutput
    ! USE modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only: numyrs, maxlat, maxlon,  &
                       fcvarinit, fcvardyn, facvar, &
                       startlatstart, startlatend, startlonstart, startlonend, inoculationtime, &
                       readstatefile, dofft
    use loggermodule
    IMPLICIT NONE
 
    LOGICAL, INTENT(in):: doParallel
    ! Passed on variables>--------------------------------------------------------------------------------
    INTEGER :: nspc, &    ! number of species                                    [=spec]
               yearStartEqRun, yearEndEqRun, &    ! year of calculation for initial run into equilibrium [=..]
               yearStart, yearEnd, &    ! year of calculation                                  [=..]
               stateYear, &    ! year of stored state
               currLatStart, currLatEnd, &    ! looping variable for latitude                        [=..]
               currLonStart, currLonEnd  ! looping variable for longitude                       [=..]
    LOGICAL :: doDispersal
 
 
 
!! This is all MASTER-WORK
 
!----- Preparation of simulation, reading in of settings and parameters  ---------------------------------- 
    ! call startmeasuretime(0,17)                        ! Comment out if run without MPI
    call readcontrolparsandinitfiles()             ! Initialises all kinds of output files, reads in the control parameters 
    
    call allocateareas()         ! Allocates all kinds of arrays for the simulation
    call getspc(nspc, dofft)     ! reads in the species parameters, and calculates further constant variables from them 
 
! Preparation of outputs
    call preparenetcdfoutput(nspc)  ! prepares the output in NetCDF format
    call prepareoutput(nspc)        ! prepares the output  
! Setting of variables for stand  
    call initandsetconstheightclprops(nspc)               ! sets cell-specific constant variables
    call preparebiocliminput()      ! prepares the reading in of the bioclimate
    
! For parallel computing transfer of initial information to slaves
    if (doparallel) then
       currlatstart = 1; currlatend = startlatend         
       currlonstart = 1; currlonend = startlonend 
!      call startmeasuretime(0,26)   ! Comment out if run without MPI  
!#ifdef WITHMPI
!        call BroadcastConstantValues(nspc, 0)
!        call SendInitValuesToSlaves(0, startlatStart, startlatEnd, startlonStart, startlonEnd, facvar, nspc, doDispersal)
!#endif
    ! call measuretime(0,26) ! Comment out if run without MPI
    end if  !doParallel
 
!----- Inoculation simulation, i.e. simulation with constant seed pool and no dispersal. ------------------------- 
    dodispersal = .false.
 
    yearstarteqrun = 0
    yearendeqrun = inoculationtime + yearstarteqrun
 
    if ((yearstarteqrun < yearendeqrun)) then ! run only if an inoculation period longer than 0 is defined
        currlatstart = startlatstart; currlatend = startlatend  ! run only in the inoculation area
        currlonstart = startlonstart; currlonend = startlonend
        facvar = fcvarinit
        write(logmessage,"(A,I6,A,I6)") "Starting inoculation from year", yearstarteqrun, " to ", yearendeqrun
              call loginfo(logmessage)
        write(logmessage,"(4(A10))") "latStart", "latEnd", "lonStart", "lonEnd";         call loginfo(logmessage)
        write(logmessage,"(4(I10))") currlatstart, currlatend, currlonstart, currlonend; call loginfo(logmessage)
        
        call timeloop(yearstarteqrun, yearendeqrun, &           ! This is the simulation
                      1, maxlat, 1, maxlon, currlatstart, currlatend, currlonstart, currlonend, &
                      facvar, nspc, dodispersal, 1, doparallel, dofft)
    end if 
 
!----- Now the simulation with migration starts.  ---------------------------------------------------------------------------   
    dodispersal = .true.  
 
    currlatstart = 1; currlatend = maxlat ! run in the full simulation domain
    currlonstart = 1; currlonend = maxlon
 
    if (readstatefile) then           ! if simulation is to be started from a statefile...
        call loginfo("Reading state file...")
        call readstate(stateyear, currlatstart, currlatend, currlonstart, currlonend, nspc) ! read this statefile
        yearstart = stateyear                     ! simulation starts at year of statefile
        yearend   = numyrs + yearstarteqrun - 1
    else
        call loginfo("Read state file disabled. Skip reading state file...")
        yearstart = yearendeqrun + 1               ! simulation starts in the year after the inoculation period
        yearend = numyrs + yearstarteqrun - 1
    end if
 
    !call OpenStateFileForWrite()
    
    write(logmessage,"(A,I6,A,I6)") "Starting migration simulation from year", yearstart, " to ", yearend
    call loginfo(logmessage)
    write(logmessage,"(4(A10))") "latStart", "latEnd", "lonStart", "lonEnd"
    call loginfo(logmessage)
    write(logmessage,"(4(I10))") currlatstart, currlatend, currlonstart, currlonend
    call loginfo(logmessage)
 
    facvar = fcvardyn
    call timeloop(yearstart, yearend, &          ! This is the simulation
                  1, maxlat, 1, maxlon, currlatstart, currlatend, currlonstart, currlonend, &
                  facvar, nspc, dodispersal, 2, doparallel, dofft)
 
!----- Finally some cleaning up ---------------------------------------------------------------------------   
 
! #ifdef WITHMPI
!     if (doParallel) then
!         ! receive end signals
!         call WaitUntilSlavesAreCompletelyReady
!         call PasteResultFilesTogether(nspc, currLatStart, currLatEnd)
!         ! call PasteStateFilesTogether(nspc, currLatStart, currLatEnd,currLonStart, currLonEnd)
!     end if
! #endif
 
    call closeoutputfiles()
    call closefile(bioclimate_file)
    call stoplogger()
end SUBROUTINE treemig