PrepareBioclimInput.f90

Go to the documentation of this file.

!==============================================================================
!
!  Name   :  PrepareBioclimInput
!
!  Remarks:  contains the SUBROUTINES
!
!            PrepareBioclimInput (<TreeMig)
!            CheckDriverNames
!==============================================================================
! !==============================================================================
SUBROUTINE preparebiocliminput()
    use filelistmodule, only: bioclimate_file
    use filehandlingmodule, only: extractandcountwords, openfiler
    use loggermodule, only: logerror, logmessage, loginfo
    use all_par, only: ndrivers, columnnamesofdrivers
    
    
    IMPLICIT NONE
    
    
    INTEGER      :: err 
    character(len=:), allocatable ::   rest
    
    
    !----- opens the bioclimate file
    call openfiler(bioclimate_file, err)    
    if (err /= 0) then
        call logerror("Could not open bioclimate file: "//bioclimate_file%path)
        error stop
    end if
    !----- extracts the header column names   
    call extractandcountwords(bioclimate_file,ndrivers, columnnamesofdrivers, rest, err)
    !print *, nDrivers,  (trim(columnNamesOfDrivers(iread  ) )//"," , iread=1, nDrivers)
    !----- checks whether these  header column names are allowed
    call checkdrivernames()
    
    !read (Bioclimate_File%unit, *) ! read header
    write (logmessage, '(A)')  "Read and checked header of "//bioclimate_file%path//", now reading first year"
    call loginfo(logmessage)
    ! read one year of the bioclimate   
    call readnewbioclim
    
end SUBROUTINE preparebiocliminput
 
!==============================================================================
! @brief CheckDriverNames  
! ***************************************** 
!==============================================================================
SUBROUTINE checkdrivernames()
    use all_par, only: alloweddrivernames,ndrivers, columnnamesofdrivers, columnlocations
    use filelistmodule, only: bioclimate_file
    use loggermodule, only: logerror
    IMPLICIT NONE
    
    
    INTEGER :: iallowed, iread, nAllowedNames
    LOGICAL ::  ok, innerok
    character(len=:), allocatable :: allowedName, readName,allowedNamesString  
    
    
    nallowednames = size(alloweddrivernames)   
    
    !---- are all required names (lon, lat, year, DD, WiT, DrStr) present? 
    !---- note, the first 6 names in allowedDriverNames are the required, the additional ones are allowed
    ok=.true.
    iallowed=0
    do while((iallowed <  6) .and. ok)  ! only the first 6 must be present
        iallowed    =  iallowed+1 
        allowedname = trim(alloweddrivernames(iallowed)) ! get one allowed name
        innerok =.false.
        iread=0
        do while((iread  < ndrivers) .and. (.not.innerok)) ! compare it to all column names
            iread = iread + 1
            readname= trim(columnnamesofdrivers(iread))
            innerok = readname  == allowedname             ! check it against one allowed name
        end do
        ok = innerok
    end do  
    if (ok ) then
        ! print *, "All required column names are present."
    else 
        call logerror("At least the required column "//trim(alloweddrivernames(iallowed))// &
                " is missing in input file "//bioclimate_file%path)
        error stop
    end if 
    
    !---- are all read column names allowed (including required) ?
    
    columnlocations(:) = 0 
    ok=.true.
    iread=0
    do while((iread < ndrivers) .and. ok)
        iread = iread + 1
        readname= trim(columnnamesofdrivers(iread) )                ! get the read in column name
        innerok =.false.
        iallowed=0
        do while((iallowed  < nallowednames) .and. (.not.innerok) ) ! compare it to all allowed names
            iallowed    =  iallowed + 1 
            allowedname =trim(alloweddrivernames(iallowed))
            innerok = readname  == allowedname          
        end do
        if (innerok)  columnlocations(iallowed)=iread   ! note, which column corresponds to the allowed name
        ok=innerok
    end do   
    
    if (ok) then
        ! print *, "ok: all column names allowed " 
    else            
        !---- make a string out of the vector of allowed driver names, with "," as a separator; only for error message
        allowednamesstring=""
        do  iallowed= 1,nallowednames-1
            allowednamesstring = allowednamesstring//trim(alloweddrivernames(iallowed))//","
        end do
        allowednamesstring = allowednamesstring//trim(alloweddrivernames(nallowednames)) 
        !---- log the error message
        call logerror("At least the column "//readname// " in input file "//bioclimate_file%path  &
                //" is not within the allowed names "// allowednamesstring )
        error stop
    end if 
    
end SUBROUTINE checkdrivernames
 
!done