ReadNewBioClim.f90

Go to the documentation of this file.

!==============================================================================
!==============================================================================
SUBROUTINE readnewbioclim
    use filelistmodule
    use loggermodule
    
    use all_par, only: newbioclim, maxlat, maxlon, latrealstart, lonrealstart, latrealend, lonrealend,&
                       cellsidelength,  unitofspatialdata,  ndrivers, columnlocations 
    IMPLICIT NONE
 
    
 
    
    INTEGER :: err, ilat, ilon, oldcctime, isite, ngridcells, newtime
    REAL    :: xr, yr, muDD, stdDD, muWiT, stdWiT, prop0DrStr, muDrStr, stdDrStr, distu, brwpr, germDrought, avnit
    REAL    :: drivervariables(nDrivers)
    REAL    :: AssignReadOrDefaultDriver
  
! Here the SUBROUTINE starts>**********************************************************************
    err = 0
    oldcctime = 0
    newbioclim%bc%muDD = -999.0 !  null value, later used for masking out
 
    ngridcells = int(((latrealend - latrealstart)*unitofspatialdata/cellsidelength + 1) & ! the total number of grid cells; is the maximum number of lines per year in the bioclimate file
                     *((lonrealend - lonrealstart)*unitofspatialdata/cellsidelength + 1))
!---- loop at least over so many lines as there are grid cells
    do isite = 1, ngridcells
        !---- read one line of drivers
    
        read (bioclimate_file%unit, *, iostat=err) drivervariables    
 
        !---- These driver variables have to be present 
        xr      = drivervariables(columnlocations(1))
        yr      = drivervariables(columnlocations(2))
        newtime = drivervariables(columnlocations(3))
        mudd    = drivervariables(columnlocations(4))
        muwit   = drivervariables(columnlocations(5))
        mudrstr = drivervariables(columnlocations(6))
        !---- These optional driver variables are assigned to the correct variables
        !---- Or they are set to default, if they are not present in the data set. The indices refer to the allowed drivers in All_par
     
        distu      = assignreadordefaultdriver(7, "Large scale disturbances (distu)   " ,ndrivers, drivervariables)
        brwpr      = assignreadordefaultdriver(8, "Browsing pressure (brwpr)          " ,ndrivers, drivervariables)
        germdrought= assignreadordefaultdriver(9, "Germination drought (germDrought)  " ,ndrivers, drivervariables)
        avnit      = assignreadordefaultdriver(10,"Nutrient availability (avnit)      " ,ndrivers, drivervariables)
        
        ! if germDrought is set to default -1, then the drought stress for the trees (muDrStr) is used
        if (abs(germdrought - (-1.0))  < 1e-5) then
            germdrought = mudrstr
        end if 
!---- the standard deviations are set to very small values, because the standard case is yearly data
!---- analogously the proportion of zero-drought years is set to 0 
!---- this is a legacy from before when these statistical parameters were used for longer periods of bioclimate
!---- maybe the stdevs and prop0DrStr can completely be omitted. To be checked        
        stddd       = 0.0000001
        stdwit      = 0.0000001
        prop0drstr  = 0
        stddrstr    = 0.0000001
!---- if the read in year (newtime) was later than the last read in year (oldcctime), then all bioclimate data were read, and the loop can be left
        if ((isite > 1) .AND. (newtime /= oldcctime)) then
            backspace(bioclimate_file%unit)
            exit
        end if
 
        ilat = 1 + nint((yr - latrealstart)*unitofspatialdata/cellsidelength)
        ilon = 1 + nint((xr - lonrealstart)*unitofspatialdata/cellsidelength)
!---- error handling if the bioclimate  region is outside the simulation region.
!---- if it is smaller, doesn't matter, then the non-read in cells are set to Null (dd= -999) and by this masked out
        if ((ilat > maxlat) .or. (ilon > maxlon)) then
            write (logmessage, "(A)") "Coordinates are outside domain in bioclimate"
            call logerror(logmessage)
            write (logmessage, "(6A15)") "yr", "xr", "ilon", "ilat", "maxlon", "maxlat"
            call logerror(logmessage)
            write (logmessage, "(2F8.7,4I15)") yr, xr, ilon, ilat, maxlon, maxlat
            call logerror(logmessage)
            error stop
        end if
!---- Assign the read in values to the right places in newBioClim
        newbioclim%cctime = newtime
 
        newbioclim%bc(ilat, ilon)%muDD       = mudd
        newbioclim%bc(ilat, ilon)%stdDD      = stddd
        newbioclim%bc(ilat, ilon)%muWiT      = muwit
        newbioclim%bc(ilat, ilon)%stdWiT     = stdwit
        newbioclim%bc(ilat, ilon)%prop0DrStr = prop0drstr
        newbioclim%bc(ilat, ilon)%muDrStr    = mudrstr
        newbioclim%bc(ilat, ilon)%stdDrStr   = stddrstr
        newbioclim%bc(ilat, ilon)%disturb    = distu
        newbioclim%bc(ilat, ilon)%brwpr      = brwpr
        newbioclim%bc(ilat, ilon)%germDrought= germdrought
        newbioclim%bc(ilat, ilon)%avnit      = avnit
        if (err /= 0) then
            exit
        end if
        oldcctime = newtime   ! update the read in time
    end do
    end SUBROUTINE readnewbioclim
 
!==============================================================================
!==============================================================================
    function assignreadordefaultdriver (idriver, drivertext, nDrivers, drivervariables) &
        result(driver)
        use all_par, only: columnlocations, driverdefault
        use loggermodule
 
        IMPLICIT NONE
 
        REAL, INTENT(in)    :: drivervariables(ndrivers)
        INTEGER, INTENT(in) :: idriver,ndrivers
        character(len=35),  INTENT(in)  :: drivertext 
        REAL   :: driver ,defaultvalue
        character(len=: ), allocatable ::defaulttext
 
        defaulttext = " not read in, set to default value "
        !---- get the default value of this (idriver) driver
        defaultvalue = driverdefault(idriver)
        !---- if the driver was read in, i.e. it has a columnlocation, it is assigned to the corresponding drivervariable
        if (columnlocations(idriver)>0) then 
            driver = drivervariables(columnlocations(idriver))
        else  ! otherwise it is set to its default value
            driver = defaultvalue
        ! write (LogMessage, "(A,A,F9.3)") drivertext,defaultText, defaultvalue
        ! call LogInfo (LogMessage)
        end if 
    end function
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
 
!done