FileHandlingModule.f90

Go to the documentation of this file.

! uses preprocessor
!==============================================================================
! Module FileHandlingModule  
! ***************************************** 
! contains
!  type declarations and constants
!  subroutines  openFileR,  openFileW, closeFile, deleteFile, extractWord, ExtractAndCountWords
!==============================================================================
 
module filehandlingmodule
    !==============================================================================
    ! Type Declaration and constants 
    ! *****************  
    !   Type Declaration of a general file
    !    different constants for file handling    
    !==============================================================================
    TYPE file
    INTEGER :: unit
    character(len=:), allocatable :: path
end TYPE file
#if defined(_WIN32)
character(2):: relativepathletter = ".\"
character(1):: pathletter   = "\"
#else
character(2):: relativepathletter = "./"
character(1):: pathletter   = "/"
#endif
character(len=3), parameter :: format_integer = "I15"
character(len=5), parameter :: format_real = "F18.6"
character(len=2), parameter :: format_logical = "L1"
character(len=1), parameter :: format_character = "A"
contains
 
!==============================================================================
!==============================================================================
SUBROUTINE openfiler(theFile, err)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    INTEGER, INTENT(out) :: err
    err = 0
    open(action='read', file=thefile%path, unit=thefile%unit, iostat=err)
end SUBROUTINE openfiler
 
!==============================================================================
!==============================================================================
SUBROUTINE openfilew(theFile, err)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    INTEGER, INTENT(out) :: err
    err = 0
    open(action='write', file=thefile%path, unit=thefile%unit,status="replace", iostat=err)
end SUBROUTINE openfilew
 
!==============================================================================
!==============================================================================
SUBROUTINE closefile(theFile)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    close(thefile%unit)
end SUBROUTINE closefile
!==============================================================================
!==============================================================================
SUBROUTINE deletefile(theFile)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    INTEGER :: err
    open(unit=thefile%unit, iostat=err, file=thefile%path, status='old')
    if (err == 0) close(thefile%unit, status='delete')
end SUBROUTINE deletefile
 
!==============================================================================
!==============================================================================
SUBROUTINE extractword(theFile, n, word, rest, err)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    INTEGER, INTENT(in) :: n
    character(len=:), allocatable, INTENT(out) :: word
    character(len=:), allocatable, INTENT(out) :: rest
    INTEGER, INTENT(out) :: err
    character(len=1024) :: buffer
    INTEGER startPos, endPos, i, j
    !--- read line into buffer
    
    read(thefile%unit, "("//format_character//")", iostat=err) buffer
    !--- find start and end of nth non blank sequence in buffer
    j= 1
    do i = 1, n     
        do while(j < len(buffer) .and. buffer(j:j) == " ") 
            j = j+1
        end do
        endpos = j+index(buffer(j:len(buffer)), " ")-2
        startpos = j
        j = endpos+1
    end do
    !--- store this sequence into word  
    word = buffer(startpos:endpos)
    rest = trim(buffer(endpos+1:len(buffer)))
end SUBROUTINE extractword
 
!==============================================================================
!==============================================================================
SUBROUTINE extractandcountwords(theFile, nwords, words, rest, err)
    IMPLICIT NONE
    TYPE(file), INTENT(in) :: theFile
    INTEGER, INTENT(out) :: nwords
    character(len=30) , INTENT(out) :: words (1:50)     
    character(len=:),   INTENT(out), allocatable  :: rest 
    INTEGER, INTENT(out) :: err
    character(len=1024) :: buffer
    character(len=:), allocatable              :: word 
    INTEGER startPos, endPos,   j 
    read(thefile%unit, "("//format_character//")", iostat=err) buffer
    j= 1
    nwords= 0
    words   = "                              "
    word=" "
    rest = trim(buffer)
    ! search the words up to the "!" separator; find the start and end positions of these words within buffer. 
    do while(nwords  <=  50 .and. len(rest) > 0 .and. word /="!") 
        nwords=nwords+1
        do while(j < len(buffer) .and. buffer(j:j) == " ") 
            j = j+1
        end do
        endpos = j+index(buffer(j:len(buffer)), " ")-2
        startpos = j
        j = endpos+1 
        word = buffer(startpos:endpos)  ! the new word            
        if (word =="!") then 
            nwords = nwords - 1 
            rest = trim(buffer(endpos :len(buffer)))
        else
            words(nwords)=word  ! store to the vector of words
            rest = trim(buffer(endpos+1:len(buffer)))
        end if 
    end do
end SUBROUTINE extractandcountwords
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!       
end module filehandlingmodule