ReadState.f90

Go to the documentation of this file.

!==============================================================================
!===============================================================
 
SUBROUTINE readstate(stateyear, latstart, latend, lonstart, lonend, nspc)
    use filelistmodule, only: statein_file
    use filehandlingmodule, only: closefile, openfiler
    use loggermodule, only: logmessage, loginfo, logerror, logwarning
    use all_par, only: simustartyear, stategrid, spec, maxhc, biothreshold, maxlat, maxlon
 
    IMPLICIT NONE
 
    ! Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in)  :: latStart, latEnd, lonStart, lonEnd          ! start and end of simulation domain      
    INTEGER, INTENT(in)  :: nspc                                        ! number of species  
    INTEGER, INTENT(out) :: stateyear                                   ! year of state output
 
    ! Local variables>---------------------------------------------------------------------------------
    INTEGER :: height, &      ! loop-counter
               isp, i, currentLine, &      ! loop-counter
               lat, lon, err, &         ! format variable
               latOffset, lonOffset, &  ! offsets to correct for different extents of statefile and simulation file
               nhtc                     ! number of hight classes
    character(len=1024) :: lineBuffer
    character(len=200) :: ioerrmsg
    character(len=100) :: nameLong
    ! Here the SUBROUTINE starts>**********************************************************************
   
    !---- initialize the state variables on the simulation domain with 0
    looplat: do lat = latstart, latend
        looplon: do lon = lonstart, lonend
            do i = 1, nspc
                stategrid(lat, lon)%sp(i)%seedBank = 0.
                stategrid(lat, lon)%sp(i)%antagonist = 0.
                do height = 0, spec(i)%maxhtc
                    stategrid(lat, lon)%sp(i)%numin(height) = 0.
                end do !height
            end do   ! i (species)
        end do looplon
    end do looplat
 
    !---- set offsets  ????
    latoffset = 0
    lonoffset = 0
 
    ! Read values, correct coordinates with offsets
    call openfiler(statein_file, err) !open the state file closed (this l. 98)
    if (err /= 0) then
        call logerror("[Statefile] Could not open statefile: "//statein_file%path)
        error stop
    end if
    backspace(statein_file%unit) !  go back one line. Why? Maybe because the first line is automatically read (Why?)
 
    currentline = 0
    do while (err == 0)           ! go through the lines of the state file 
        ! keep track of currentLine
        currentline = currentline + 1
 
        ! read in line to buffer
        read (statein_file%unit, "(A)", iostat=err,   iomsg=ioerrmsg) linebuffer
 
        ! check for EOF/errors
        if (err < 0) then ! EOF
            exit;
        else if (err > 0) then ! error
            write (logmessage, "(A,I10)") "[Statfile] Could not read line in statefile. Line: ", currentline
            call logerror(logmessage)
            call logerror("[Statfile][Details] io-msg: "//ioerrmsg)
            write (logmessage, "(A,I3)") "[Statfile][Details] io-stat: ",err
            call logerror(logmessage)
            call logerror("[Statfile][Details] statefile path: "//statein_file%path)            
            call logerror("[Statfile][Details] line: "//linebuffer)
            error stop
        end if
 
        ! first read the species name (nameLong) to get get maxhtc (otherwise we dont know how many vars to read in)
        ! also read lat lon for bounds check
        read (linebuffer, *, iostat=err) namelong, stateyear, lat, lon;
 
        ! error handling of read call
        if(err /= 0) then
            write (logmessage, "(A,I10)") "[Statfile] Could not parse line in statefile. Line: ", currentline
            call logerror(logmessage)
            call logerror("[Statfile][Details] line content: "//linebuffer)
            error stop
        end if
 
        ! check bounds of lat and lon
        if(lat+latoffset > maxlat .or. lat+latoffset < 0 .or. lon+lonoffset > maxlon .or. lon+lonoffset < 0) then
            write (logmessage, "(A,I10)") "[Statfile] lat/lon are out of bounds in statefile. Line: ", currentline
            call logerror(logmessage)
            write (logmessage, "(A,I7,',',I7)") "[Statfile][Details] (latOffset, lonOffset): ", latoffset, lonoffset
            call logerror(logmessage)
            write (logmessage, "(A,I7,',',I7)") "[Statfile][Details] (lat,lon) inc. offset : ", lat+latoffset, lon+lonoffset
            call logerror(logmessage)
            write (logmessage, "(A,I7,',',I7)") "[Statfile][Details] (maxlat,maxlon)       : ", maxlat, maxlon
            call logerror(logmessage)
            call logerror("[Statfile][Details] line content: "//linebuffer)
            error stop
        end if
 
        ! find the species-idx
        do isp = 1, nspc
            if(namelong == spec(isp)%nl) exit; ! after exiting isp is the correct index 
        end do
 
        ! check if we found the species-idx
        if (isp > nspc) then
            ! species does not exist in our species selection, skip
            !write (LogMessage, "(A, I10)") "[Statfile] Ignoring species '"// trim(nameLong)// "' on line: ", currentLine
            !call LogWarning(LogMessage)
            continue
        else
            ! species is one of the selected species, load all values and store them to stateGrid, for species isp and in the different height classes
            read (linebuffer, *, iostat=err) namelong, stateyear, lat, lon, &
                stategrid(lat + latoffset, lon + lonoffset)%sp(isp)%seedBank, &
                stategrid(lat + latoffset, lon + lonoffset)%sp(isp)%antagonist, &
                nhtc, &
                (stategrid(lat + latoffset, lon + lonoffset)%sp(isp)%numin(height), height=0, min(spec(isp)%maxhtc,nhtc))
 
            ! error handling of read call
            if (err /= 0) then
                write (logmessage, "(A,I10)") "[Statfile] Could not parse line in statefile. Line: ", currentline
                call logerror(logmessage)
                call logerror("[Details] line content: "//linebuffer)
                error stop
            end if
 
        end if
    end do ! while  (err==0)
 
 
    write (logmessage, "(A,I7)") "[Statefile] Reading statefile complete. State year:",stateyear
    call loginfo(logmessage)
 
    call closefile(statein_file)    
    if(stateyear-simustartyear < 0)then
        write (logmessage, "(A,I6,A,I6,A)") "[Statfile] State-file year is smaller than the simulation start year."&
        "State-file year will be set to start year. (",stateyear,"->",simustartyear,")"
        call logwarning(logmessage)
        stateyear = 0
    else
        stateyear = stateyear-simustartyear
    end if
 
end SUBROUTINE readstate
!done