SpatialDynOneTimeStep.f90

Go to the documentation of this file.

!==============================================================================
!
!  Name   :  SpatialDynOneTimeSteo
!
!  Remarks:  contains the SUBROUTINEs
!
!            SpatialDynOneTimeStep (<TimeLoop<TreeMig)
!            LocalDynOneTimeStep (<SpatialDynOneTimeStep<TimeLoop<TreeMig)
!
!==============================================================================
! design          : H. Lischke, N. Zimmermann
! author(s)       : H. Lischke, N. Zimmermann
! implementation  : H. Lischke, N. Zimmermann
! cleaner         : T.J. Loeffler
! copyright       : (c) 1999, 03 by H. Lischke
!==============================================================================
 
!=================== For non parallel (i.e.) standard TreeMig======================================================
!===============================================================
SUBROUTINE spatialdynonetimestep(year, &
                                 currLatStart, currLatEnd, currLonStart, currLonEnd, &
                                 nspc, doDispersal, doFFT)
    ! <CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    IMPLICIT NONE
    ! <Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in)    :: year, &  ! current year
                              currLatStart, currLatEnd, currLonStart, currLonEnd, &  ! start and end of simulated areaINTEGER :: nspc
                              nspc                                   ! number of species involved [=spec]
 
    LOGICAL, INTENT(in)    :: doDispersal, doFFT                                 ! dispersal or not?
 
    ! <Local variables>--------------------------------------------------------------------------------
    INTEGER :: lat, &    ! looping variable for latitude              [=..]
               lon, &                 ! looping variable for longitude
               iam       ! processor or slave number
    REAL:: ddegs, wtemp, drstr, avnit, brwpr, disturb, germDrought
    ! <Here the SUBROUTINE starts>**********************************************************************
!        print *, "begin localwork ", year, "currLatStart, currLatEnd,currLonStart, currLonEnd ",&
!                                         currLatStart, currLatEnd,currLonStart, currLonEnd
 !----  Dynamics in cells
    looplatlocadyn: do lat = currlatstart, currlatend
        looplonlocadyn: do lon = currlonstart, currlonend
          !---- Get the current environment for this cell   
            call getenvfactors(year, lat, lon,  ddegs, wtemp, drstr, avnit, brwpr, disturb, germdrought  )
          !---- Local dynamics in this cell
            call localdynonetimestep(year, lat, lon, nspc, &
                    ddegs, wtemp, drstr, avnit, brwpr, disturb, germdrought, dodispersal, dofft)
        end do looplonlocadyn
    end do looplatlocadyn
    !---- write the results to netcdf file if wished
    call reportnetcdf(year, nspc)
 !---- Seed dynamics
    !---- do seed dispersal by fft is wished
    if (dodispersal .and. dofft) &
            call seedrainbyfft(nspc, year, currlatstart, currlatend, currlonstart, currlonend)
    !---- update the new seeds ending up in this simulation area   
    call updatenewseeds(nspc, iam, dodispersal, year, currlatstart, currlatend, currlonstart, currlonend)           !For compatibility with parallel version         ! In Interact.f90
    !---- Get seeds from outside the simulation region
    call seedsfromoutssimregion(nspc, dodispersal, year, currlatstart, currlatend, currlonstart, currlonend)          ! In Interact.f90
end SUBROUTINE spatialdynonetimestep
!****<Here the SUBROUTINE ends>********************************************************************
!=================== For non parallel (i.e.) standard TreeMig======================================================
!===============================================================
 
!========================= For parallel and sequential ===============================
SUBROUTINE localdynonetimestep(year, lat, lon, nspc, ddegs, wtemp, drstr, avnit, brwpr, disturb, germDrought, doDispersal, doFFT)
    
    use all_par, only: stockability, currstateincell, maxlat, maxlon
    use loggermodule
    IMPLICIT NONE
    
    INTEGER, INTENT(in)    :: year, nspc, lat, lon                                   ! number of species involved [=spec]
    LOGICAL, INTENT(in)    :: doDispersal, doFFT                                  ! dispersal or not?
    REAL, INTENT(in)    :: ddegs, wtemp, drstr, avnit, brwpr, disturb, germDrought
 
    TYPE(currstateincell):: thiscell
 
    
    ! check whether cell is in allowed area
    if ((lat > maxlat) .or. (lat < 1) .or. (lon > maxlon) .or. (lon < 1)) then
        call logerror("Wrong coordinates in SUBROUTINE LocalDynOneTimeStep")
        write (logmessage, "(4A15)") "lon", "lat", "maxlon", "maxlat"
        call logerror(logmessage)
        write (logmessage, "(4I15)") lon, lat, maxlon, maxlat
        call logerror(logmessage)
        error stop
    end if
    ! if not stockable, shown by a negative value of ddegs...
    if (ddegs < 0.0 .and. stockability(lat, lon) > 0.0) then
        call killalltreesandseeds(nspc, thiscell) ! set all trees and seeds to zero
        call storethiscellspecstatestocell(lat, lon, nspc, thiscell)        ! store the actual structure thiscell back to the cell,         ! In StoringBackAndForth.f90
        stockability(lat, lon) = 0.0  ! set the stockability to zero
    end if
!print *," in localwork", year,lat, lon ,   stockability(lat, lon), ddegs
    
    if (stockability(lat, lon) > 1.e-20) then  ! if cell is stockable, do the local dynamics
        call calccurrentdepfunctsincell(nspc, ddegs, wtemp, drstr, avnit, brwpr, germdrought) ! calculate dep functions
        call storecellstatetothiscell(lat, lon, nspc, ddegs, wtemp, drstr, avnit, brwpr, disturb, germdrought, thiscell)     ! store the actual cell to the structure thiscell  ! In StoringBackAndForth.f90
        call localforestdynamics(nspc, year, dodispersal, thiscell)         ! do the local forest dynamics
        call storethiscellspecstatestocell(lat, lon, nspc, thiscell)        ! store the actual structure thiscell back to the cell,         ! In StoringBackAndForth.f90
 
        if (dodispersal .and. (.not. dofft)) call seedsdispersedfromthiscell(nspc, lat, lon) !!! calculate the seed dispersal from this cell,                                       ! In   Interact.f90
!     else 
!         call StoreCellStateToThisCell(lat, lon, nspc, ddegs, wtemp, drstr, avnit, brwpr, disturb, germDrought, thiscell)     ! store the actual cell to the structure thiscell  ! In StoringBackAndForth.f90
!         call KillAllTrees(nspc, year, thiscell)
!         call StoreThisCellSpecStatesToCell(lat, lon, nspc, thiscell)        ! store the actual structure thiscell back to the cell,         ! In StoringBackAndForth.f90
    end if  !stockability(lat, lon) > 1.E-20
 
    call report(nspc, year, lat, lon)
    !      call EvaluateResults (nspc, year, lat, lon)
    end SUBROUTINE localdynonetimestep
    
!========================= Setting all trees and seeds to zero when cell becomes unstockable ===============================
!****<Here the SUBROUTINE ends>********************************************************************
!=================== For non parallel (i.e.) standard TreeMig======================================================
!===============================================================
    SUBROUTINE killalltreesandseeds(nspc, thiscell)
       use all_par, only:  currstateincell 
       IMPLICIT NONE
       TYPE(currstateincell), INTENT(inout):: thiscell
       INTEGER, INTENT(in) :: nspc
       INTEGER  :: ispec
      
       do ispec = 1, nspc
           thiscell%sp(ispec)%numin      = 0.0
           thiscell%sp(ispec)%sb         = 0.0
           thiscell%sp(ispec)%seedBank    = 0.0
       end do
    end SUBROUTINE killalltreesandseeds
!done