WriteState.f90

Go to the documentation of this file.

!==============================================================================
SUBROUTINE writestate(year, latStart, latEnd, lonStart, lonEnd, nspc)
    use all_par, only: experimentid
    use loggermodule, only: loginfo, logmessage
    use filelistmodule, only: statebackupout_file,statebackupout_file_1,statebackupout_file_0,stateout_file
    use filehandlingmodule, only: relativepathletter, deletefile
    !  CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only:   simustartyear, numyrs, stateoutputdist, stateoutputyears
    
    IMPLICIT NONE
    !  Local variables ---------------------------------------------------------------------------------
    character*6:: yearChar
   
    ! <Passed variables >--------------------------------------------------------------------------------
    INTEGER, INTENT(in)    :: year                  !  year of calculation 
    INTEGER, INTENT(in)    :: latStart, latEnd, lonStart, lonEnd, nspc   !  start and end of simulated area                              
 
    
    ! <Here the SUBROUTINE starts>**********************************************************************
    if (year >0)  then
        ! ---- Check whether this is a year for regular backup
        if((mod(year, stateoutputdist) == 0) .and. (year /= numyrs-1)) then
            write (logmessage, "(A,I7)") "Writing backup state for year: ", year
            call loginfo(logmessage)
            ! ---- write out alternatively between 2 backup statefiles, in case of crash during writing. Delete the other one.
            if(mod(year/stateoutputdist, 2) == 1) then
                call writestatefile(statebackupout_file_0, year, latstart, latend, lonstart, lonend, nspc) 
            else 
                call writestatefile(statebackupout_file_1, year, latstart, latend, lonstart, lonend, nspc) 
            end if
            if(mod(year/stateoutputdist, 2) == 1) then
                call deletefile(statebackupout_file_1)
            else
                call deletefile(statebackupout_file_0)
            end if
        end if
        ! ---- if  this is the (nearly) last year, write out an additional backup file, and delete the two others
        if(year == numyrs-1) then
            write (logmessage, "(A,I7)") "Writing backup state for year: ", year
            call loginfo(logmessage)
            call writestatefile(statebackupout_file, year, latstart, latend, lonstart, lonend, nspc)        
            call deletefile(statebackupout_file_1)
            call deletefile(statebackupout_file_0)
        end if
        ! ---- If this is a year for explicitly wished output of state, write the state to the statefile with the name containing the experimentid and the year 
        if (any((year + simustartyear) == stateoutputyears)) then
            write (logmessage, "(A,I7)") "Writing state optionally for year: ", year
            call loginfo(logmessage)
            write(yearchar,"(I6.2)")  year + simustartyear
            stateout_file%path     =  relativepathletter//"S/"//experimentid//"/statefile_"//trim(adjustl(yearchar))//".txt" 
            call writestatefile(stateout_file, year, latstart, latend, lonstart, lonend, nspc) 
        end if 
    end if
end SUBROUTINE writestate
 
! ==============================================================================
! ===============================================================
SUBROUTINE writestatefile(stateFile, year, latStart, latEnd, lonStart, lonEnd, nspc)
    use filehandlingmodule, only: file, closefile, openfilew
    use loggermodule, only: logwarning
    ! <Passed variables>--------------------------------------------------------------------------------
    TYPE(file), INTENT(in) :: stateFile
    INTEGER, INTENT(in)    :: year, &                                   !  year of calculation [=..]
            latStart, latEnd, lonStart, lonEnd, nspc   !  start and end of simulated area                          !  start and end of simulated area
    ! <Local variables>---------------------------------------------------------------------------------
    INTEGER :: err
    call openfilew(statefile, err)
    if(err /= 0) then
        call logwarning("Could not open statefile!  Skip writing")
        return;
    end if
    call writestateloops(year, latstart, latend, lonstart, lonend, nspc, statefile%unit)
    call closefile(statefile)
end SUBROUTINE writestatefile
! ==============================================================================
! ===============================================================
 
SUBROUTINE writestateloops(year, latstart, latend, lonstart, lonend, nspc, unit)
    use all_par, only:  stategrid, spec, stockability, simustartyear
    ! CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    
    IMPLICIT NONE
    
    ! <Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in)    :: year,  &                                   !> year of calculation [=..]
            latStart, latEnd, lonStart, lonEnd, nspc, unit
    
    ! <Local variables>---------------------------------------------------------------------------------
    INTEGER :: height
    INTEGER :: isp, &                !>!> species loop-counter
            lat, lon, output_year
    character(len=5) :: asChar_maxhtc
    ! ---- converts the relative year to the real year of output then written to the statefile
    output_year = year + simustartyear
    ! ---- loop over the gridcells
    looplat: do lat = latstart, latend
        looplon: do lon = lonstart, lonend
            if (stockability(lat, lon) .gt. 0) then
    ! ---- loop over the species
                do isp = 1, nspc
                    write (aschar_maxhtc, "(I5)")  spec(isp)%maxhtc+1
    ! ---- write out the state of the species in this grid cell
                    write (unit, "(A,3I10,2F18.6,I5,"//aschar_maxhtc//"F18.6)") spec(isp)%nl, output_year, lat, lon, &
                            stategrid(lat, lon)%sp(isp)%seedBank, &
                            stategrid(lat, lon)%sp(isp)%antagonist, &
                            spec(isp)%maxhtc, &
                            (stategrid(lat, lon)%sp(isp)%numin(height), height=0, spec(isp)%maxhtc)
                end do
            end if
        end do looplon
    end do looplat
end SUBROUTINE writestateloops