SpecImmigration.f90

Go to the documentation of this file.

!==============================================================================
!
!  Name   :  SpecImmigration
!
!  Purpose:  determines the immigration of seedlings
!
!  Remarks:  contains the SUBROUTINE
!
!            SpecImmigration (<LocalDynOneTimeStep<LocalDynOneTimeStep<
!                               DistrLocalDynThisTime<TimeLoop<TreeMig)
!
!==============================================================================
! design          : H. Lischke, N. Zimmermann
! author(s)       : H. Lischke, N. Zimmermann
! implementation  : H. Lischke, N. Zimmermann
! cleaner         : T.J. Loeffler
! copyright       : (c) 1999, 03 by H. Lischke
!==============================================================================
!===================================================================== 
!===============================================================
 
SUBROUTINE specimmigration(nspc, year, doDispersal, thiscell)
 
    ! <CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only: potbirth, pltsiz, &
                       maxlat, maxlon, &
                       spec, immiperiod, &
                       immigration, currstateincell
    ! Use control, species and stand  parameters
    IMPLICIT NONE
 
    ! <Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in) :: nspc, year           ! number of species                                  [=spec]
    Logical, INTENT(in) :: doDispersal
 
    ! <Local variables>---------------------------------------------------------------------------------
    INTEGER :: immilatcoord, immiloncoord, &      !  looping variable for species and light
               iimm, i
    TYPE(currstateincell), INTENT(inout) :: thiscell
 
    ! <Here the SUBROUTINE starts>**********************************************************************
    byspecies: do i = 1, nspc
        if (dodispersal) then
            if (immigration) then
                !----- Immigration (sapling inflow) at certain times and cells
                do iimm = 1, spec(i)%immi%n
                     !-----  the relative immigration coords are converted to coords (0 to maxlat, 0 to maxlon)
                    immilatcoord = int(max(1.0, maxlat*spec(i)%immi%dat(iimm)%relLat))
                    immiloncoord = int(max(1.0, maxlon*spec(i)%immi%dat(iimm)%relLon))
                     !-----  if current year and coords fall into the immigration period and are an immigration point, 
                     !-----  the saplings number is increased  
                    if ((thiscell%lat == immilatcoord) .and. &
                        (thiscell%lon == immiloncoord) .and. &
                        (year >= spec(i)%immi%dat(iimm)%year - immiperiod) .and. &
                        (year <  spec(i)%immi%dat(iimm)%year + immiperiod)) then
                        thiscell%sp(i)%numin(0) = thiscell%sp(i)%numin(0) + 1000.0*pltsiz/833.0
                    end if
                end do !----- iimm
            end if !----- immigration
        else !----- not doDispersal
            if (immigration) then
                if (year >= spec(i)%immi%dat(1)%year) then
                    spec(i)%birth = potbirth
                else
                    spec(i)%birth = 0
                end if
            else !----- not immigration
                spec(i)%birth = potbirth
            end if !----- IF immigration
        end if !----- immigration
    end do byspecies
 
end SUBROUTINE specimmigration
!done