Mort.f90

Go to the documentation of this file.

!==============================================================================
!
!  Name   :  Mort
!
!  Purpose:
!
!  Remarks:  contains the SUBROUTINE
!
!            Mort (<LocalDynOneTimeStep<LocalDynOneTimeStep<DistrLocalDynThisTime<
!                    TimeLoop<TreeMig)
!
!==============================================================================
! design          : H. Lischke, N. Zimmermann
! author(s)       : H. Lischke, N. Zimmermann
! implementation  : H. Lischke, N. Zimmermann
! cleaner         : T.J. Loeffler
! copyright       : (c) 1999, 03 by H. Lischke
!==============================================================================
!===================================================================== 
!===============================================================
SUBROUTINE mort(isp, heightcl, lightcl, srvinhl, numb, disturbanceMort, thiscell)
 
    ! <CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only: speccl, spec, currstateincell      ! Use species parameters
 
    IMPLICIT NONE
 
    ! <Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in) :: isp, &   ! number of species                                      [=spec]
                           heightcl, &   ! height class                                         [=height]
                           lightcl       ! light class                                           [=ilight]
    REAL, INTENT(in)    :: numb     ! # of trees                       [=nInH  <- rNoTreesUnderCond]
    REAL, INTENT(in)    :: disturbanceMort  ! mortality in this cell by disturbance
    REAL, INTENT(out)   :: srvinhl     ! remaining ind. per spec/heightcl/light class         [=survNInH]
 
    ! <Local variables>---------------------------------------------------------------------------------
    REAL :: gfc, &               ! Stress factor due to growth stress               [=rStessDepDiam]
            efc, &               ! Stress factor due to env. stress               [=rStressDepOther]
            cmp, &               ! Comparison of growth- and enviro.-stress factors       [=compare]
            cmplow, &               ! This is "cmp" of the lower light class              [=compareOld]
            vmort, &               ! Stress related mortality                           [=rStresvmort]
            tmort                   ! Total mortality (constant & stress based)            [=totalMort]
 
    TYPE(currstateincell), INTENT(inout):: thiscell
    ! <Here the SUBROUTINE starts>**********************************************************************
    !----- determine, whether growth dependent vitality is bigger than threshold (0.0003)
    gfc = speccl(isp)%growthVitality(heightcl, lightcl)/0.0003
 
    !-----determine, whether environment dependent vitality is bigger than threshold (0.1)
    efc = speccl(isp)%envVitality(heightcl, lightcl)/0.1
 
    !----- get the more severe of them (minimum)
    cmp = min(gfc, efc)
 
    if (cmp < 1.0) then !----- if lower vitality  below threshold, set variable mortality to 1
        vmort = 1.0
    else ! -----determine mortalities in next lower light class
        if (lightcl > 1) then !----- more light than in first light class
            if (cmp == efc) then
                cmplow = speccl(isp)%envVitality(heightcl, lightcl - 1)/0.1
            else
                cmplow = speccl(isp)%growthVitality(heightcl, lightcl - 1)/0.0003
            end if
        else !----- first light class, verrrry dark!
            cmplow = 0.0
        end if
 
        !----- interpolate if next lower light class is below threshold
        if (cmplow < 1.0) then
            vmort = (1.0 - cmplow)/(cmp - cmplow)
        else
            vmort = 0.0
        end if
    end if
    !----- determine total mortality
    ! if (heightcl >= 0) then
    if (heightcl > 0) then
        tmort = min(spec(isp)%cmort + disturbancemort + vmort*0.184, 1.0) ! Mortality is assumed to act only after 3 subseqent bad years, but distributed over the years
    else
        tmort = min(spec(isp)%cmort + disturbancemort + vmort, 1.0)         ! Mortality is assumed to act directly in sapling heigth class
        !   tmort = MIN (spec(isp)%cmort + disturbanceMort + vmort* 0.184, 1.0)    !
    end if
    !----- determine survivors
    srvinhl = (1.0 - tmort)*numb
    !----- update state variable
    thiscell%sp(isp)%numin(heightcl) = thiscell%sp(isp)%numin(heightcl) - (tmort*numb)
    if (thiscell%sp(isp)%numin(heightcl) < 0) then
        thiscell%sp(isp)%numin(heightcl) = 0.0
    end if
 
end SUBROUTINE mort
!done