SelfRegulation.f90

Go to the documentation of this file.

!===================================================================== 
!===============================================================
SUBROUTINE selfregulation(nspc, doDispersal, thiscell)
 
    ! <CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only: pltsiz, &
                       withseedantagonists, &
                       seedantamort, seedantarain, &
                       seedantagraz, seedantaeff, &
                       withseedcarrcap, seedcarrcap, currstateincell
    ! Use control, species and stand parameters
    IMPLICIT NONE
 
    ! <Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in) :: nspc     ! number of species                                     [=spec]
    Logical, INTENT(in) :: doDispersal
 
    ! <Local variables>---------------------------------------------------------------------------------
    INTEGER :: i                      ! looping variable for species and light
    REAL    :: seedBankUngrazed, grazing, grazersOld, sharePerGrazer, amountPerGrazer, &
               ratio, exporatio
    TYPE(currstateincell), INTENT(inout):: thiscell
 
    ! <Here the SUBROUTINE starts>**********************************************************************
    byspecies: do i = 1, nspc
        if (dodispersal) then ! only if dispersal, because otherwise no seed bank
            !----- if wished antagonists eat seeds from seedBank and grow
            if (withseedantagonists) then
                grazersold = thiscell%sp(i)%antagonist
                seedbankungrazed = thiscell%sp(i)%seedBank + thiscell%sp(i)%newSeeds
                sharepergrazer = 1/(grazersold + 0.5/seedantagraz)
                amountpergrazer = seedbankungrazed*sharepergrazer
                grazing = grazersold*amountpergrazer
 
                !----- they can eat only as much as is there
                thiscell%sp(i)%seedBank = seedbankungrazed - grazing
                thiscell%sp(i)%antagonist = (grazersold + grazing*seedantaeff)*(1.-seedantamort) + &
                                            seedantarain*pltsiz/833.0
            end if !----- withseedAntagonists
 
            !-----  more abstract: the antagonist dynamics is formulated by a simple carrying capacity
            !-----  This is assumed to work continuously during each year. That means the dynamics is a solved logistic equation
            if (withseedcarrcap) then
                ratio = min(thiscell%sp(i)%newSeeds/seedcarrcap, 20.0) ! it is 0 anyway with values smaller exp(-20)
                exporatio = exp(-ratio)
                thiscell%sp(i)%seedBank = seedcarrcap + (thiscell%sp(i)%seedBank - seedcarrcap)*exporatio
                !----- technical trick to avoid 0 trees with very little influx
                if ((ratio > 0.0) .AND. (thiscell%sp(i)%seedBank == 0.0)) thiscell%sp(i)%seedBank = thiscell%sp(i)%newSeeds
            end if !----- withSeedCarrCap
 
            if ((.not. withseedcarrcap) .and. (.not. withseedantagonists)) then ! ----- this case happens only in reprotest
                thiscell%sp(i)%seedBank = thiscell%sp(i)%seedBank + thiscell%sp(i)%newSeeds
            end if
 
            thiscell%sp(i)%sb = thiscell%sp(i)%seedBank !-----  
            thiscell%sp(i)%newSeeds = 0.0; 
        end if !----- doDispersal
 
    end do byspecies
 
end SUBROUTINE selfregulation
!done