ReadImmigrationData.f90

Go to the documentation of this file.

!==============================================================================
!===============================================================
SUBROUTINE readimmigrationdata(nspc)
    use loggermodule
    use filelistmodule
    ! CALL modules for TYPE definitions and +- fixed variables>---------------------------------------------------------------
    use all_par, only: simustartyear, &
                       spec, &
                       immigration, immiperiod, maximmigrationsperspec
 
    IMPLICIT NONE
 
    ! Passed variables>--------------------------------------------------------------------------------
    INTEGER, INTENT(in) :: nspc        ! number of species   [=spec]
 
    ! Local variables>---------------------------------------------------------------------------------
    INTEGER       :: i, j, &           ! looping variable for species and immigration dates
                     err, &
                     imdat(maxImmigrationsPerSpec)
    character(27) :: text1
 
    ! Here the SUBROUTINE starts>**********************************************************************
    !-----<Check for file (opening) errors>
    if (immigration) then
        call loginfo("Reading immigration data")
        call openfiler(immigration_file, err) ! closed (this l. 85)
        if (err /= 0) then
            call logerror("Could not open file with immigration data: "//immigration_file%path)
            error stop
        end if
        call openfiler(immigrationout_file, err)   ! closed (this l. 86)
        !----- Read immigration period
        read (immigration_file%unit, "(A)")        ! skip first line
        read (immigration_file%unit, *) immiperiod ! read the immigration period, i.e. the length of immigration event
 
        !----- Skip first
        read (immigration_file%unit, "(A)")
        read_specimmi: do i = 1, nspc ! for each species ...
            read (immigration_file%unit, *, iostat=err) text1, spec(i)%immi%n, & ! read the number of immigration events... 
                (imdat(j), spec(i)%immi%dat(j)%relLat, spec(i)%immi%dat(j)%relLon, j=1, spec(i)%immi%n) ! ... and for each event year (in real years), relLat and relLon; the coordinates are relative values (between 0 and 1)
 
            if (spec(i)%immi%n .gt. maximmigrationsperspec) then
                write (logmessage, *) 'more immigration events ', spec(i)%immi%n, ' than allowed ', maximmigrationsperspec
                call logerror(logmessage)
                error stop
            end if
 
            !----- If EOF, then exit the read loop
            exit_loop1: if (err /= 0) then
                exit read_specimmi
            end if exit_loop1
 
            do j = 1, spec(i)%immi%n ! transform immigration year to relative years (years since simulation start)
                spec(i)%immi%dat(j)%year = -simustartyear + imdat(j)
            end do
 
            write (immigrationout_file%unit, *) &
                spec(i)%immi%n, (spec(i)%immi%dat(j)%year, &
                                 spec(i)%immi%dat(j)%relLat, spec(i)%immi%dat(j)%relLon, j=1, spec(i)%immi%n)
        end do read_specimmi
 
        call closefile(immigration_file)
        call closefile(immigrationout_file)
    else   !----- no immigration, initialize at least first year
        spec%immi%n = 0
        spec%immi%dat(1)%year = 0
 
    end if !----- immigration
end SUBROUTINE readimmigrationdata
!done